plant-it: init at 0.10.0 (#404158)

maintainers/maintainer-list.nix

@@ -7441,6 +7441,11 @@
     githubId = 5085029;
     name = "Emanuele Peruffo";
   };
+  epireyn = {
+    github = "epireyn";
+    githubId = 48213068;
+    name = "Edgar Pireyn";
+  };
   equirosa = {
     email = "eduardo@eduardoquiros.com";
     github = "equirosa";

pkgs/by-name/pl/plant-it-frontend/package.nix

@@ -0,0 +1,19 @@
+{
+  lib,
+  flutter326,
+  plant-it,
+}:
+
+flutter326.buildFlutterApplication {
+  pname = "plant-it-frontend";
+  inherit (plant-it) version src;
+  sourceRoot = "source/frontend";
+
+  targetFlutterPlatform = "web";
+
+  pubspecLock = lib.importJSON ./pubspec.lock.json;
+
+  meta = plant-it.meta // {
+    description = "Frontend for Plant It";
+  };
+}

pkgs/by-name/pl/plant-it/Remove-test-needing-internet-connection.patch

@@ -0,0 +1,14 @@
+--- backend/src/test/resources/features/plants-and-species.feature
++++ backend/src/test/resources/features/plants-and-species.feature
+@@ -199,11 +199,8 @@
+     Then response is ok
+     * species "foo" is
+       | scientific_name | synonyms | family | genus | species | creator | externalId |
+       | foo             | synonym1 | fam    | gen   | foo     | USER    |            |
+-    * species "foo" has this image
+-      | image_id | image_url                | image_content |
+-      |          | https://dummyimage.com/1 |               |
+     * species "foo" has this care
+       | light | humidity | minTemp | maxTemp | phMax | phMin |
+       | 6     | 5        |         |         | 2     | 1     |
+     When user updates botanical info "foo"

pkgs/by-name/pl/plant-it/package.nix

@@ -0,0 +1,49 @@
+{
+  maven,
+  jdk21_headless,
+  makeBinaryWrapper,
+  lib,
+  fetchFromGitHub,
+}:
+let
+  version = "0.10.0";
+in
+maven.buildMavenPackage {
+  pname = "plant-it";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "MDeLuise";
+    repo = "plant-it";
+    tag = version;
+    hash = "sha256-QnujZecUu7bzllSsrLH6hSZMaWeOUXBrSZ5rbT56pDM=";
+  };
+  sourceRoot = "source/backend";
+
+  mvnHash = "sha256-3YQOZMXMI6BrHkqud2OKColJWbDXfwnAwRifYxbleqI=";
+  nativeBuildInputs = [
+    makeBinaryWrapper
+  ];
+
+  patches = [ ./Remove-test-needing-internet-connection.patch ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 target/plant-it-*.jar $out/share/plant-it/plant-it.jar
+
+    makeBinaryWrapper ${jdk21_headless}/bin/java $out/bin/plant-it --add-flags "-jar $out/share/plant-it/plant-it.jar"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    changelog = "https://github.com/MDeLuise/plant-it/releases/tag/${version}";
+    description = "Self-hosted gardening companion application";
+    homepage = "https://plant-it.org";
+    maintainers = with lib.maintainers; [ epireyn ];
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.unix;
+    mainProgram = "plant-it";
+  };
+}