proselint: migrate to by-name, modernize, adopt

pkgs/by-name/pr/proselint/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  writableTmpDirAsHomeHook,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "proselint";
+  version = "0.14.0";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "amperser";
+    repo = "proselint";
+    tag = version;
+    hash = "sha256-bI5gkckXUa640GOb5U5NW4i2op4fn0LKoPHFSIwbheM=";
+  };
+
+  build-system = [ python3Packages.poetry-core ];
+
+  dependencies = [ python3Packages.click ];
+
+  nativeCheckInputs = [
+    python3Packages.pytestCheckHook
+    writableTmpDirAsHomeHook
+  ];
+
+  pythonImportsCheck = [ "proselint" ];
+
+  meta = {
+    description = "Linter for prose";
+    mainProgram = "proselint";
+    homepage = "https://github.com/amperser/proselint";
+    changelog = "https://github.com/amperser/proselint/releases/tag/${version}/CHANGELOG.md";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.pbsds ];
+  };
+}

pkgs/tools/text/proselint/default.nix

@@ -1,37 +0,0 @@
-{
-  lib,
-  python3Packages,
-  fetchurl,
-  buildPythonApplication,
-  click,
-}:
-buildPythonApplication rec {
-  pname = "proselint";
-  version = "0.14.0";
-
-  doCheck = false; # fails to pass because it tries to run in home directory
-  format = "pyproject";
-
-  src = fetchurl {
-    url = "mirror://pypi/p/proselint/${pname}-${version}.tar.gz";
-    sha256 = "YklkJyvqFHZ+XfJWHYfdMHZ5OMjLUvsjWFvDdYBoDoY=";
-  };
-
-  nativeBuildInputs = [ python3Packages.poetry-core ];
-  propagatedBuildInputs = [ click ];
-
-  meta = with lib; {
-    description = "A linter for prose.";
-    mainProgram = "proselint";
-
-    homepage = "https://github.com/amperser/proselint";
-    changelog = "https://github.com/amperser/proselint/blob/main/CHANGELOG.md#proselint${
-      lib.replaceStrings [ "." ] [ "" ] version
-    }";
-
-    downloadPage = "https://pypi.org/project/proselint/${version}/#files";
-
-    license = licenses.bsd3;
-    maintainers = [ ];
-  };
-}

pkgs/top-level/all-packages.nix

@@ -10281,11 +10281,6 @@ with pkgs;
 
   proj_7 = callPackage ../development/libraries/proj/7.nix { };
 
-  proselint = callPackage ../tools/text/proselint {
-    inherit (python3Packages)
-    buildPythonApplication click;
-  };
-
   prospector = callPackage ../development/tools/prospector { };
 
   protobuf = protobuf_29;