From 4ed60fd7aa459030e0275a04d686d3e48bdd92ed Mon Sep 17 00:00:00 2001
From: lucasew <lucas59356@gmail.com>
Date: Fri, 23 May 2025 16:19:24 -0300
Subject: [PATCH] enroot: init at 3.5.0

Signed-off-by: lucasew <lucas59356@gmail.com>
---
 pkgs/by-name/en/enroot/package.nix | 52 ++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/by-name/en/enroot/package.nix

diff --git a/pkgs/by-name/en/enroot/package.nix b/pkgs/by-name/en/enroot/package.nix
new file mode 100644
index 000000000000..0cf1e5027bb2
--- /dev/null
+++ b/pkgs/by-name/en/enroot/package.nix
@@ -0,0 +1,52 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  flock,
+  gitUpdater,
+  bashInteractive,
+  lib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "enroot";
+  version = "3.5.0";
+
+  src = fetchFromGitHub {
+    owner = "NVIDIA";
+    repo = "enroot";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Sw4kfsb0Gi21At2pU8lt5wIfCih7VZ7Zf9/62xBKKRU=";
+    fetchSubmodules = true;
+  };
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail 'git submodule update' 'echo git submodule update'
+  '';
+
+  makeTarget = "install";
+  makeFlags = [
+    "DESTDIR=${placeholder "out"}"
+    "prefix=/"
+  ];
+
+  nativeBuildInputs = [
+    flock
+  ];
+
+  buildInputs = [
+    bashInteractive
+  ];
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = {
+    description = "Simple yet powerful tool to turn traditional container/OS images into unprivileged sandboxes";
+    license = lib.licenses.asl20;
+    homepage = "https://github.com/NVIDIA/enroot";
+    changelog = "https://github.com/NVIDIA/enroot/releases/tag/v${finalAttrs.version}";
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.lucasew ];
+    mainProgram = "enroot";
+  };
+})