From 57d927ab1c4e36b996ec1a34e09333abed8a8e46 Mon Sep 17 00:00:00 2001
From: Curran McConnell <curran@mercury.com>
Date: Wed, 26 Mar 2025 16:27:51 -0400
Subject: [PATCH] chalk: init at 1.29.4

---
 pkgs/by-name/ch/chalk/package.nix | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 pkgs/by-name/ch/chalk/package.nix

diff --git a/pkgs/by-name/ch/chalk/package.nix b/pkgs/by-name/ch/chalk/package.nix
new file mode 100644
index 000000000000..06543f7c1a90
--- /dev/null
+++ b/pkgs/by-name/ch/chalk/package.nix
@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+let
+  # This derivation is adapted from the
+  # install script that Chalk recommends: https://api.chalk.ai/install.sh
+  chalkVersion = "1.29.4";
+  chalkPathPiecesByNixSystem = {
+    "aarch64-darwin" = "Darwin/aarch64";
+    "x86_64-darwin" = "Darwin/x86_64";
+    "aarch64-linux" = "Linux/aarch64";
+    "x86_64-linux" = "Linux/x86_64";
+  };
+  chalkHashByNixSystem = {
+    "aarch64-darwin" = "sha256-zHPfyeHdHfbxrUhjLJHbLkeuu7WwK4jtYX7bk5wimX0=";
+    "x86_64-darwin" = "sha256-D6lBrnBlD+OU5kQv6b6BzK+u7vB91rTtYpz8iBUeWdA=";
+    "aarch64-linux" = "sha256-XHaCLxVJbXjPILczDGWLFqP0q/nBO5O2A9lghkvM474=";
+    "x86_64-linux" = "sha256-hlNljLJm+m7l+Djni+ATKyWKSGKSDP0YN3CuJ4fXmWg=";
+  };
+  chalkHash = chalkHashByNixSystem."${stdenv.system}";
+  chalkPathPieces = chalkPathPiecesByNixSystem."${stdenv.system}";
+  chalkUrl = "https://api.chalk.ai/v1/install/${chalkPathPieces}/v${chalkVersion}";
+in
+stdenv.mkDerivation {
+  pname = "chalk";
+  version = chalkVersion;
+  src = fetchurl {
+    url = chalkUrl;
+    hash = chalkHash;
+  };
+  dontUnpack = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm 555 $src $out/bin/chalk
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "CLI tool for interacting with the Chalk platform";
+    homepage = "https://docs.chalk.ai/cli";
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    license = lib.licenses.unfree;
+    maintainers = with lib.maintainers; [ curran ];
+    mainProgram = "chalk";
+    platforms = [
+      "x86_64-linux"
+      "x86_64-darwin"
+      "aarch64-linux"
+      "aarch64-darwin"
+    ];
+  };
+}