From 1d2776003776234c7eb05a6eaa0ad73261b15af0 Mon Sep 17 00:00:00 2001
From: Louis Thevenet <louis.tvnt@gmail.com>
Date: Mon, 28 Apr 2025 15:09:57 +0200
Subject: [PATCH] mcat: init at 0.2.8

---
 pkgs/by-name/mc/mcat-unwrapped/package.nix | 34 ++++++++++++++++++++++
 pkgs/by-name/mc/mcat/package.nix           | 24 +++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/mc/mcat-unwrapped/package.nix
 create mode 100644 pkgs/by-name/mc/mcat/package.nix

diff --git a/pkgs/by-name/mc/mcat-unwrapped/package.nix b/pkgs/by-name/mc/mcat-unwrapped/package.nix
new file mode 100644
index 000000000000..9732a5dfd3ab
--- /dev/null
+++ b/pkgs/by-name/mc/mcat-unwrapped/package.nix
@@ -0,0 +1,34 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "mcat-unwrapped";
+  version = "0.2.8";
+
+  src = fetchFromGitHub {
+    owner = "Skardyy";
+    repo = "mcat";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-XvZBikp+Q/pe80eOTQj2rKZ14kXEUBjIroWsh8xmr8A=";
+  };
+
+  cargoHash = "sha256-DIvKCPyqD82IgOqs7+fsAz3sj5IkXacxfZOttSEQ1aA=";
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "cat command for documents / images / videos and more!";
+    homepage = "https://github.com/Skardyy/mcat";
+    changelog = "https://github.com/Skardyy/mcat/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    mainProgram = "mcat";
+    maintainers = with lib.maintainers; [
+      louis-thevenet
+    ];
+  };
+})
diff --git a/pkgs/by-name/mc/mcat/package.nix b/pkgs/by-name/mc/mcat/package.nix
new file mode 100644
index 000000000000..9af71573fb08
--- /dev/null
+++ b/pkgs/by-name/mc/mcat/package.nix
@@ -0,0 +1,24 @@
+{
+  runCommand,
+  mcat-unwrapped,
+  makeWrapper,
+  lib,
+  chromium,
+  ffmpeg-headless,
+  useChromium ? false,
+  useFfmpeg ? false,
+}:
+
+runCommand "mcat"
+  {
+    pname = "mcat";
+    inherit (mcat-unwrapped) version meta;
+
+    nativeBuildInputs = [ makeWrapper ];
+  }
+  ''
+    mkdir -p $out/bin
+    makeWrapper ${lib.getExe mcat-unwrapped} $out/bin/mcat --prefix PATH : ${
+      lib.makeBinPath ((lib.optional useChromium chromium) ++ (lib.optional useFfmpeg ffmpeg-headless))
+    }
+  ''