movefasta/nixpkgs
1
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2025-06-11 12:15:34 +03:00
Code Issues Projects Releases Packages Wiki Activity

kahip: init at 3.18

Browse source
This commit is contained in:
qbisi 2025-04-20 01:33:32 +08:00
parent c2d7322efd
commit 9c1b7551e6
2 changed files with 73 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

66
pkgs/by-name/ka/kahip/package.nix Normal file
View file

@ -0,0 +1,66 @@
{
lib,
stdenv,
fetchFromGitHub,
fetchpatch2,
cmake,
mpi,
metis,
python3Packages,
pythonSupport ? false,
isILP64 ? false,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "kahip";
version = "3.18";
src = fetchFromGitHub {
owner = "KaHIP";
repo = "KaHIP";
tag = "v${finalAttrs.version}";
hash = "sha256-l8DhVb2G6pQQcH3Wq4NsKw30cSK3sG+gCYRdpibw4ZI=";
};
patches = [
(fetchpatch2 {
url = "https://github.com/KaHIP/KaHIP/commit/9d4978c7540a1ccbc9807367d6e3852114e86567.patch?full_index=1";
hash = "sha256-nIJL0YmVp9+JUhzEXjoabD1qNEnhtrBnjMWnitYt0eU=";
})
];
nativeBuildInputs =
[ cmake ]
++ lib.optionals pythonSupport [
python3Packages.python
python3Packages.pybind11
];
buildInputs = [
mpi
metis
];
cmakeFlags = [
(lib.cmakeBool "64BITMODE" isILP64)
(lib.cmakeBool "BUILDPYTHONMODULE" pythonSupport)
(lib.cmakeFeature "CMAKE_INSTALL_PYTHONDIR" python3Packages.python.sitePackages)
];
doInstallCheck = pythonSupport;
nativeInstallCheckInputs = lib.optionals pythonSupport [
python3Packages.pythonImportsCheckHook
];
pythonImportsCheck = [ "kahip" ];
meta = {
homepage = "https://kahip.github.io/";
downloadPage = "https://github.com/KaHIP/KaHIP/";
changelog = "https://github.com/KaHIP/KaHIP/releases/tag/v${finalAttrs.version}";
description = "Karlsruhe HIGH Quality Partitioning";
license = lib.licenses.mit;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ qbisi ];
};
})

7
pkgs/top-level/python-packages.nix
View file

@ -7282,6 +7282,13 @@ self: super: with self; {
kaggle = callPackage ../development/python-modules/kaggle { }; kaggle = callPackage ../development/python-modules/kaggle { };
kahip = toPythonModule (
pkgs.kahip.override {
pythonSupport = true;
python3Packages = self;
}
);
kaitaistruct = callPackage ../development/python-modules/kaitaistruct { }; kaitaistruct = callPackage ../development/python-modules/kaitaistruct { };
kajiki = callPackage ../development/python-modules/kajiki { }; kajiki = callPackage ../development/python-modules/kajiki { };