nixos/prometheus-fastly-exporter: fix runtime environment

- Make the token a required option
- Drop the proto from the listen parameter
- Use systemd credentials to pass the token file
- Drop debug flag, use extraArgs instead
- Actually hook up extraArgs
- Escape shell arguments
- Drop overly broad `with lib` statement

nixos/modules/services/monitoring/prometheus/exporters/fastly.nix

@@ -1,41 +1,54 @@
-{ config, lib, pkgs, options }:
+{ config
+, lib
+, pkgs
+, options
+}:
 
-with lib;
+let
+  inherit (lib)
+    escapeShellArgs
+    mkOption
+    optionals
+    types
+  ;
 
-let cfg = config.services.prometheus.exporters.fastly;
+  cfg = config.services.prometheus.exporters.fastly;
 in
 {
   port = 9118;
-  extraOpts = {
+  extraOpts = with types; {
-    debug = mkEnableOption (lib.mdDoc "Debug logging mode for fastly-exporter");
-
     configFile = mkOption {
-      type = types.nullOr types.path;
+      type = nullOr path;
       default = null;
-      description = lib.mdDoc ''
+      example = "./fastly-exporter-config.txt";
+      description = ''
         Path to a fastly-exporter configuration file.
         Example one can be generated with `fastly-exporter --config-file-example`.
       '';
-      example = "./fastly-exporter-config.txt";
     };
 
     tokenPath = mkOption {
-      type = types.nullOr types.path;
+      type = path;
-      apply = final: if final == null then null else toString final;
+      description = ''
-      description = lib.mdDoc ''
         A run-time path to the token file, which is supposed to be provisioned
         outside of Nix store.
       '';
     };
   };
   serviceOpts = {
-    script = ''
+    serviceConfig = {
-      ${optionalString (cfg.tokenPath != null)
+      LoadCredential = "fastly-api-token:${cfg.tokenPath}";
-      "export FASTLY_API_TOKEN=$(cat ${toString cfg.tokenPath})"}
+    };
-      ${pkgs.prometheus-fastly-exporter}/bin/fastly-exporter \
+    script = let
-        -listen http://${cfg.listenAddress}:${toString cfg.port}
+      call = escapeShellArgs ([
-        ${optionalString cfg.debug "-debug true"} \
+        "${pkgs.prometheus-fastly-exporter}/bin/fastly-exporter"
-        ${optionalString (cfg.configFile != null) "-config-file ${cfg.configFile}"}
+        "-listen" "${cfg.listenAddress}:${toString cfg.port}"
+      ] ++ optionals (cfg.configFile != null) [
+        "--config-file" cfg.configFile
+      ] ++ cfg.extraFlags);
+    in ''
+      export FASTLY_API_TOKEN="$(cat $CREDENTIALS_DIRECTORY/fastly-api-token)"
+      ${call}
     '';
   };
 }