movefasta/nixpkgs
1
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2025-06-09 19:13:26 +03:00
Code Issues Projects Releases Packages Wiki Activity

cloudflare-cli: init at 4.2.0

Browse source
This commit is contained in:
Defelo 2025-03-12 11:31:01 +01:00
parent d817fcbaba
commit e7706ec0df
No known key found for this signature in database
GPG key ID: 2A05272471204DD3
1 changed files with 53 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

53
pkgs/by-name/cl/cloudflare-cli/package.nix Normal file
View file

@ -0,0 +1,53 @@
{
lib,
stdenv,
fetchFromGitHub,
fetchYarnDeps,
yarnConfigHook,
yarnInstallHook,
nodejs,
nix-update-script,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "cloudflare-cli";
version = "4.2.0";
src = fetchFromGitHub {
owner = "danielpigott";
repo = "cloudflare-cli";
tag = "v${finalAttrs.version}";
hash = "sha256-cT+cMekXhHKfFi+dH1dCA/YNBSyYePJIZBSkDMPZZ14=";
};
yarnOfflineCache = fetchYarnDeps {
yarnLock = finalAttrs.src + "/yarn.lock";
hash = "sha256-0SFXgaLQE/MkqC9id7DAiP422tEyTt2gpgpIdXViFBI=";
};
nativeBuildInputs = [
yarnConfigHook
yarnInstallHook
nodejs
];
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/cfcli --help >/dev/null
runHook postInstallCheck
'';
passthru.updateScript = nix-update-script { };
meta = {
description = "CLI for interacting with Cloudflare";
homepage = "https://github.com/danielpigott/cloudflare-cli";
changelog = "https://github.com/danielpigott/cloudflare-cli/releases/tag/v${finalAttrs.version}";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ defelo ];
mainProgram = "cfcli";
};
})