anakron: init at 0.3.1 (#389852)

maintainers/maintainer-list.nix

@@ -6905,6 +6905,12 @@
     githubId = 10106819;
     name = "eilvelia";
   };
+  ejiektpobehuk = {
+    email = "oss@ejiek.id";
+    github = "ejiektpobehuk";
+    githubId = 7649041;
+    name = "Vlad Petrov";
+  };
   eken = {
     email = "edvin.kallstrom@protonmail.com";
     github = "Eken-beep";

pkgs/by-name/an/anakron/package.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+  xorg,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "anakron";
+  version = "0.3.1";
+
+  src = fetchzip {
+    url = "https://github.com/molarmanful/ANAKRON/releases/download/v${version}/ANAKRON-release_v${version}.zip";
+    hash = "sha256-YggeGSFc+NoDUZjV/cEhQGUR278f97X+WpcDLY66iqg";
+  };
+
+  nativeBuildInputs = [ xorg.mkfontscale ];
+
+  installPhase = ''
+    runHook preInstall
+
+    misc="$out/share/fonts/misc"
+    install -D -m 644 *.{bdf,otb,pcf} -t "$misc"
+    install -D -m 644 *.psfu -t "$out/share/consolefonts"
+    install -D -m 644 *.ttf -t "$out/share/fonts/truetype"
+
+    # create fonts.dir so NixOS xorg module adds to fp
+    mkfontdir "$misc"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Thicc retrofuturistic bitmap font made for the modern screen";
+    homepage = "https://github.com/molarmanful/ANAKRON";
+    changelog = "https://github.com/molarmanful/ANAKRON/releases/tag/v${version}";
+    license = lib.licenses.ofl;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      ejiektpobehuk
+    ];
+  };
+}