mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-09 19:13:26 +03:00
c464c44a42
Since DEs like KDE Plasma 6, GNOME and COSMIC are not designed to be X11-exclusive, putting them under `services.xserver` is misleading. In particular, GNOME defaults to Wayland these days and X11 support is going to be dropped in near future. Let’s follow Plasma and move GNOME NixOS options out of `xserver` attribute. This patch does not include any changes to X11 support itself. Signed-off-by: John Titor <50095635+JohnRTitor@users.noreply.github.com>
55 lines
1.3 KiB
Nix
55 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
cfg = config.programs.nautilus-open-any-terminal;
|
|
in
|
|
{
|
|
options.programs.nautilus-open-any-terminal = {
|
|
enable = lib.mkEnableOption "nautilus-open-any-terminal";
|
|
|
|
terminal = lib.mkOption {
|
|
type = with lib.types; nullOr str;
|
|
default = null;
|
|
description = ''
|
|
The terminal emulator to add to context-entry of nautilus. Supported terminal
|
|
emulators are listed in https://github.com/Stunkymonkey/nautilus-open-any-terminal#supported-terminal-emulators.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
environment.systemPackages = with pkgs; [
|
|
nautilus-python
|
|
nautilus-open-any-terminal
|
|
];
|
|
|
|
environment.sessionVariables = lib.mkIf (!config.services.desktopManager.gnome.enable) {
|
|
NAUTILUS_4_EXTENSION_DIR = "${pkgs.nautilus-python}/lib/nautilus/extensions-4";
|
|
};
|
|
|
|
environment.pathsToLink = [
|
|
"/share/nautilus-python/extensions"
|
|
];
|
|
|
|
programs.dconf = lib.optionalAttrs (cfg.terminal != null) {
|
|
enable = true;
|
|
profiles.user.databases = [
|
|
{
|
|
settings."com/github/stunkymonkey/nautilus-open-any-terminal".terminal = cfg.terminal;
|
|
lockAll = true;
|
|
}
|
|
];
|
|
};
|
|
};
|
|
meta = {
|
|
maintainers = with lib.maintainers; [
|
|
stunkymonkey
|
|
linsui
|
|
];
|
|
};
|
|
}
|