mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-12 04:35:41 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
86 lines
2.3 KiB
Nix
86 lines
2.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
utils,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.nginx.sso;
|
|
format = pkgs.formats.yaml { };
|
|
configPath = "/var/lib/nginx-sso/config.yaml";
|
|
in
|
|
{
|
|
options.services.nginx.sso = {
|
|
enable = lib.mkEnableOption "nginx-sso service";
|
|
|
|
package = lib.mkPackageOption pkgs "nginx-sso" { };
|
|
|
|
configuration = lib.mkOption {
|
|
type = format.type;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
listen = { addr = "127.0.0.1"; port = 8080; };
|
|
|
|
providers.token.tokens = {
|
|
myuser = {
|
|
_secret = "/path/to/secret/token.txt"; # File content should be the secret token
|
|
};
|
|
};
|
|
|
|
acl = {
|
|
rule_sets = [
|
|
{
|
|
rules = [ { field = "x-application"; equals = "MyApp"; } ];
|
|
allow = [ "myuser" ];
|
|
}
|
|
];
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
nginx-sso configuration
|
|
([documentation](https://github.com/Luzifer/nginx-sso/wiki/Main-Configuration))
|
|
as a Nix attribute set.
|
|
|
|
Options containing secret data should be set to an attribute set
|
|
with the singleton attribute `_secret` - a string value set to the path
|
|
to the file containing the secret value which should be used in the
|
|
configuration. This file must be readable by `nginx-sso`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
systemd.services.nginx-sso = {
|
|
description = "Nginx SSO Backend";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
StateDirectory = "nginx-sso";
|
|
WorkingDirectory = "/var/lib/nginx-sso";
|
|
ExecStartPre = pkgs.writeShellScript "merge-nginx-sso-config" ''
|
|
rm -f '${configPath}'
|
|
# Relies on YAML being a superset of JSON
|
|
${utils.genJqSecretsReplacementSnippet cfg.configuration configPath}
|
|
'';
|
|
ExecStart = ''
|
|
${lib.getExe cfg.package} \
|
|
--config ${configPath} \
|
|
--frontend-dir ${lib.getBin cfg.package}/share/frontend
|
|
'';
|
|
Restart = "always";
|
|
User = "nginx-sso";
|
|
Group = "nginx-sso";
|
|
};
|
|
};
|
|
|
|
users.users.nginx-sso = {
|
|
isSystemUser = true;
|
|
group = "nginx-sso";
|
|
};
|
|
|
|
users.groups.nginx-sso = { };
|
|
};
|
|
}
|