mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-09 19:13:26 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
96 lines
2.7 KiB
Nix
96 lines
2.7 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
|
|
cfg = config.virtualisation.docker.rootless;
|
|
proxy_env = config.networking.proxy.envVars;
|
|
settingsFormat = pkgs.formats.json { };
|
|
daemonSettingsFile = settingsFormat.generate "daemon.json" cfg.daemon.settings;
|
|
|
|
in
|
|
|
|
{
|
|
###### interface
|
|
|
|
options.virtualisation.docker.rootless = {
|
|
enable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
This option enables docker in a rootless mode, a daemon that manages
|
|
linux containers. To interact with the daemon, one needs to set
|
|
{command}`DOCKER_HOST=unix://$XDG_RUNTIME_DIR/docker.sock`.
|
|
'';
|
|
};
|
|
|
|
setSocketVariable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Point {command}`DOCKER_HOST` to rootless Docker instance for
|
|
normal users by default.
|
|
'';
|
|
};
|
|
|
|
daemon.settings = lib.mkOption {
|
|
type = settingsFormat.type;
|
|
default = { };
|
|
example = {
|
|
ipv6 = true;
|
|
"fixed-cidr-v6" = "fd00::/80";
|
|
};
|
|
description = ''
|
|
Configuration for docker daemon. The attributes are serialized to JSON used as daemon.conf.
|
|
See https://docs.docker.com/engine/reference/commandline/dockerd/#daemon-configuration-file
|
|
'';
|
|
};
|
|
|
|
package = lib.mkPackageOption pkgs "docker" { };
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
environment.systemPackages = [ cfg.package ];
|
|
|
|
environment.extraInit = lib.optionalString cfg.setSocketVariable ''
|
|
if [ -z "$DOCKER_HOST" -a -n "$XDG_RUNTIME_DIR" ]; then
|
|
export DOCKER_HOST="unix://$XDG_RUNTIME_DIR/docker.sock"
|
|
fi
|
|
'';
|
|
|
|
# Taken from https://github.com/moby/moby/blob/master/contrib/dockerd-rootless-setuptool.sh
|
|
systemd.user.services.docker = {
|
|
wantedBy = [ "default.target" ];
|
|
description = "Docker Application Container Engine (Rootless)";
|
|
# needs newuidmap from pkgs.shadow
|
|
path = [ "/run/wrappers" ];
|
|
environment = proxy_env;
|
|
unitConfig = {
|
|
# docker-rootless doesn't support running as root.
|
|
ConditionUser = "!root";
|
|
StartLimitInterval = "60s";
|
|
};
|
|
serviceConfig = {
|
|
Type = "notify";
|
|
ExecStart = "${cfg.package}/bin/dockerd-rootless --config-file=${daemonSettingsFile}";
|
|
ExecReload = "${pkgs.procps}/bin/kill -s HUP $MAINPID";
|
|
TimeoutSec = 0;
|
|
RestartSec = 2;
|
|
Restart = "always";
|
|
StartLimitBurst = 3;
|
|
LimitNOFILE = "infinity";
|
|
LimitNPROC = "infinity";
|
|
LimitCORE = "infinity";
|
|
Delegate = true;
|
|
NotifyAccess = "all";
|
|
KillMode = "mixed";
|
|
};
|
|
};
|
|
};
|
|
|
|
}
|