mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-17 06:59:46 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
49 lines
1.3 KiB
Nix
49 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
cfg = config.hardware.amdgpu;
|
|
in
|
|
{
|
|
options.hardware.amdgpu = {
|
|
legacySupport.enable = lib.mkEnableOption ''
|
|
using `amdgpu` kernel driver instead of `radeon` for Southern Islands
|
|
(Radeon HD 7000) series and Sea Islands (Radeon HD 8000)
|
|
series cards. Note: this removes support for analog video outputs,
|
|
which is only available in the `radeon` driver
|
|
'';
|
|
initrd.enable = lib.mkEnableOption ''
|
|
loading `amdgpu` kernelModule in stage 1.
|
|
Can fix lower resolution in boot screen during initramfs phase
|
|
'';
|
|
opencl.enable = lib.mkEnableOption ''OpenCL support using ROCM runtime library'';
|
|
# cfg.amdvlk option is defined in ./amdvlk.nix module
|
|
};
|
|
|
|
config = {
|
|
boot.kernelParams = lib.optionals cfg.legacySupport.enable [
|
|
"amdgpu.si_support=1"
|
|
"amdgpu.cik_support=1"
|
|
"radeon.si_support=0"
|
|
"radeon.cik_support=0"
|
|
];
|
|
|
|
boot.initrd.kernelModules = lib.optionals cfg.initrd.enable [ "amdgpu" ];
|
|
|
|
hardware.graphics = lib.mkIf cfg.opencl.enable {
|
|
enable = lib.mkDefault true;
|
|
extraPackages = [
|
|
pkgs.rocmPackages.clr
|
|
pkgs.rocmPackages.clr.icd
|
|
];
|
|
};
|
|
};
|
|
|
|
meta = {
|
|
maintainers = with lib.maintainers; [ johnrtitor ];
|
|
};
|
|
}
|