mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-19 07:59:24 +03:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
69 lines
1.7 KiB
Nix
69 lines
1.7 KiB
Nix
# This module adds Memtest86+ to the GRUB boot menu.
|
|
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
memtest86 = pkgs.memtest86plus;
|
|
cfg = config.boot.loader.grub.memtest86;
|
|
in
|
|
|
|
{
|
|
options = {
|
|
|
|
boot.loader.grub.memtest86 = {
|
|
|
|
enable = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Make Memtest86+, a memory testing program, available from the GRUB
|
|
boot menu.
|
|
'';
|
|
};
|
|
|
|
params = mkOption {
|
|
default = [];
|
|
example = [ "console=ttyS0,115200" ];
|
|
type = types.listOf types.str;
|
|
description = ''
|
|
Parameters added to the Memtest86+ command line. As of memtest86+ 5.01
|
|
the following list of (apparently undocumented) parameters are
|
|
accepted:
|
|
|
|
- `console=...`, set up a serial console.
|
|
Examples:
|
|
`console=ttyS0`,
|
|
`console=ttyS0,9600` or
|
|
`console=ttyS0,115200n8`.
|
|
|
|
- `btrace`, enable boot trace.
|
|
|
|
- `maxcpus=N`, limit number of CPUs.
|
|
|
|
- `onepass`, run one pass and exit if there
|
|
are no errors.
|
|
|
|
- `tstlist=...`, list of tests to run.
|
|
Example: `0,1,2`.
|
|
|
|
- `cpumask=...`, set a CPU mask, to select CPUs
|
|
to use for testing.
|
|
|
|
This list of command line options was obtained by reading the
|
|
Memtest86+ source code.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
boot.loader.grub.extraEntries = ''
|
|
menuentry "Memtest86+" {
|
|
linux @bootRoot@/memtest.bin ${toString cfg.params}
|
|
}
|
|
'';
|
|
boot.loader.grub.extraFiles."memtest.bin" = "${memtest86}/memtest.bin";
|
|
};
|
|
}
|