mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-13 05:05:29 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
84 lines
2 KiB
Nix
84 lines
2 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.dictd;
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.dictd = {
|
|
|
|
enable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to enable the DICT.org dictionary server.
|
|
'';
|
|
};
|
|
|
|
DBs = lib.mkOption {
|
|
type = lib.types.listOf lib.types.package;
|
|
default = with pkgs.dictdDBs; [
|
|
wiktionary
|
|
wordnet
|
|
];
|
|
defaultText = lib.literalExpression "with pkgs.dictdDBs; [ wiktionary wordnet ]";
|
|
example = lib.literalExpression "[ pkgs.dictdDBs.nld2eng ]";
|
|
description = "List of databases to make available.";
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config =
|
|
let
|
|
dictdb = pkgs.dictDBCollector {
|
|
dictlist = map (x: {
|
|
name = x.name;
|
|
filename = x;
|
|
}) cfg.DBs;
|
|
};
|
|
in
|
|
lib.mkIf cfg.enable {
|
|
|
|
# get the command line client on system path to make some use of the service
|
|
environment.systemPackages = [ pkgs.dict ];
|
|
|
|
environment.etc."dict.conf".text = ''
|
|
server localhost
|
|
'';
|
|
|
|
users.users.dictd = {
|
|
group = "dictd";
|
|
description = "DICT.org dictd server";
|
|
home = "${dictdb}/share/dictd";
|
|
uid = config.ids.uids.dictd;
|
|
};
|
|
|
|
users.groups.dictd.gid = config.ids.gids.dictd;
|
|
|
|
systemd.services.dictd = {
|
|
description = "DICT.org Dictionary Server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
environment = {
|
|
LOCALE_ARCHIVE = "/run/current-system/sw/lib/locale/locale-archive";
|
|
};
|
|
# Work around the fact that dictd doesn't handle SIGTERM; it terminates
|
|
# with code 143 instead of exiting with code 0.
|
|
serviceConfig.SuccessExitStatus = [ 143 ];
|
|
serviceConfig.Type = "forking";
|
|
script = "${pkgs.dict}/sbin/dictd -s -c ${dictdb}/share/dictd/dictd.conf --locale en_US.UTF-8";
|
|
};
|
|
};
|
|
}
|