mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-13 05:05:29 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
90 lines
1.9 KiB
Nix
90 lines
1.9 KiB
Nix
# Module for the IPv6 Router Advertisement Daemon.
|
|
|
|
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.radvd;
|
|
|
|
confFile = pkgs.writeText "radvd.conf" cfg.config;
|
|
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options.services.radvd = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to enable the Router Advertisement Daemon
|
|
({command}`radvd`), which provides link-local
|
|
advertisements of IPv6 router addresses and prefixes using
|
|
the Neighbor Discovery Protocol (NDP). This enables
|
|
stateless address autoconfiguration in IPv6 clients on the
|
|
network.
|
|
'';
|
|
};
|
|
|
|
package = mkPackageOption pkgs "radvd" { };
|
|
|
|
debugLevel = mkOption {
|
|
type = types.int;
|
|
default = 0;
|
|
example = 5;
|
|
description = ''
|
|
The debugging level is an integer in the range from 1 to 5,
|
|
from quiet to very verbose. A debugging level of 0 completely
|
|
turns off debugging.
|
|
'';
|
|
};
|
|
|
|
config = mkOption {
|
|
type = types.lines;
|
|
example = ''
|
|
interface eth0 {
|
|
AdvSendAdvert on;
|
|
prefix 2001:db8:1234:5678::/64 { };
|
|
};
|
|
'';
|
|
description = ''
|
|
The contents of the radvd configuration file.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
users.users.radvd = {
|
|
isSystemUser = true;
|
|
group = "radvd";
|
|
description = "Router Advertisement Daemon User";
|
|
};
|
|
users.groups.radvd = { };
|
|
|
|
systemd.services.radvd = {
|
|
description = "IPv6 Router Advertisement Daemon";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
serviceConfig = {
|
|
ExecStart = "@${cfg.package}/bin/radvd radvd -n -u radvd -d ${toString cfg.debugLevel} -C ${confFile}";
|
|
Restart = "always";
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
}
|