mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-13 05:05:29 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
80 lines
1.8 KiB
Nix
80 lines
1.8 KiB
Nix
{
|
|
config,
|
|
pkgs,
|
|
lib,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
{
|
|
options = {
|
|
services.toxvpn = {
|
|
enable = mkEnableOption "toxvpn running on startup";
|
|
|
|
localip = mkOption {
|
|
type = types.str;
|
|
default = "10.123.123.1";
|
|
description = "your ip on the vpn";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 33445;
|
|
description = "udp port for toxcore, port-forward to help with connectivity if you run many nodes behind one NAT";
|
|
};
|
|
|
|
auto_add_peers = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [ ];
|
|
example = [
|
|
"toxid1"
|
|
"toxid2"
|
|
];
|
|
description = "peers to automatically connect to on startup";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf config.services.toxvpn.enable {
|
|
systemd.services.toxvpn = {
|
|
description = "toxvpn daemon";
|
|
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
|
|
preStart = ''
|
|
mkdir -p /run/toxvpn || true
|
|
chown toxvpn /run/toxvpn
|
|
'';
|
|
|
|
path = [ pkgs.toxvpn ];
|
|
|
|
script = ''
|
|
exec toxvpn -i ${config.services.toxvpn.localip} -l /run/toxvpn/control -u toxvpn -p ${toString config.services.toxvpn.port} ${
|
|
lib.concatMapStringsSep " " (x: "-a ${x}") config.services.toxvpn.auto_add_peers
|
|
}
|
|
'';
|
|
|
|
serviceConfig = {
|
|
KillMode = "process";
|
|
Restart = "on-success";
|
|
Type = "notify";
|
|
};
|
|
|
|
restartIfChanged = false; # Likely to be used for remote admin
|
|
};
|
|
|
|
environment.systemPackages = [ pkgs.toxvpn ];
|
|
|
|
users.users = {
|
|
toxvpn = {
|
|
isSystemUser = true;
|
|
group = "toxvpn";
|
|
home = "/var/lib/toxvpn";
|
|
createHome = true;
|
|
};
|
|
};
|
|
users.groups.toxvpn = { };
|
|
};
|
|
}
|