mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-10 11:45:45 +03:00
eb96c8dc5b
Every postgresql testcase essentially does the following things:
* Filter `postgresqlVersions` for server packages
* Filter postgresql server packages for suitable ones (i.e. extensions
must support the given version)
* Generate an attribute-set of testcases
The first item became necessary in
7ab1e88833 given that
`postgresql/default.nix` now exposes JIT and non-JIT servers AND a
`libpq` that is not suitable for the tests here.
This changes restructures this a little bit, i.e.:
* Having an attribute-set that contains a bunch of postgresql servers
and a single client package seems odd (and the sole consumer of
`postgresqlVersions` in nixpkgs, the test suite, has to take that into
account). Hence, postgresql's default.nix now provides `libpq` (the client)
and a `postgresqlVersions` attribute with all supported JIT and non-JIT
variants of postgresql.
* Each test-case gets a third argument, a function called `genTests`:
this function sets `recurseForDerivations = true;` and generates an
attribute-set of tests for each postgresql version given a function
that returns a testcase or multiple test-cases (`makeTestFor`). The
argument to `makeTestFor` is a postgresql server package.
This function also accepts a filter predicate that is passed against
`filterAttrs` to remove postgresql server packages that are not
suitable for the test (e.g. because the version isn't supported by the
extension to test).
I checked by making sure that the `.drv` doesn't change on staging with
this change on top for postgresq, postgresql-jit,
postgresql-wal-receiver, postgresql-tls-client-cert, anonymizer, pgjwt,
pgvecto-rs, timescaledb, tsja and wal2json.
98 lines
2.5 KiB
Nix
98 lines
2.5 KiB
Nix
{
|
|
pkgs,
|
|
makeTest,
|
|
genTests,
|
|
}:
|
|
|
|
let
|
|
inherit (pkgs) lib;
|
|
|
|
test-sql = pkgs.writeText "postgresql-test" ''
|
|
CREATE EXTENSION timescaledb;
|
|
CREATE EXTENSION timescaledb_toolkit;
|
|
|
|
CREATE TABLE sth (
|
|
time TIMESTAMPTZ NOT NULL,
|
|
value DOUBLE PRECISION
|
|
);
|
|
|
|
SELECT create_hypertable('sth', 'time');
|
|
|
|
INSERT INTO sth (time, value) VALUES
|
|
('2003-04-12 04:05:06 America/New_York', 1.0),
|
|
('2003-04-12 04:05:07 America/New_York', 2.0),
|
|
('2003-04-12 04:05:08 America/New_York', 3.0),
|
|
('2003-04-12 04:05:09 America/New_York', 4.0),
|
|
('2003-04-12 04:05:10 America/New_York', 5.0)
|
|
;
|
|
|
|
WITH t AS (
|
|
SELECT
|
|
time_bucket('1 day'::interval, time) AS dt,
|
|
stats_agg(value) AS stats
|
|
FROM sth
|
|
GROUP BY time_bucket('1 day'::interval, time)
|
|
)
|
|
SELECT
|
|
average(stats)
|
|
FROM t;
|
|
|
|
SELECT * FROM sth;
|
|
'';
|
|
|
|
makeTestFor =
|
|
package:
|
|
makeTest {
|
|
name = "timescaledb-${package.name}";
|
|
meta = with lib.maintainers; {
|
|
maintainers = [ typetetris ];
|
|
};
|
|
|
|
nodes.machine =
|
|
{ ... }:
|
|
{
|
|
services.postgresql = {
|
|
inherit package;
|
|
enable = true;
|
|
enableJIT = lib.hasInfix "-jit-" package.name;
|
|
extensions =
|
|
ps: with ps; [
|
|
timescaledb
|
|
timescaledb_toolkit
|
|
];
|
|
settings = {
|
|
shared_preload_libraries = "timescaledb, timescaledb_toolkit";
|
|
};
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
def check_count(statement, lines):
|
|
return 'test $(sudo -u postgres psql postgres -tAc "{}"|wc -l) -eq {}'.format(
|
|
statement, lines
|
|
)
|
|
|
|
|
|
machine.start()
|
|
machine.wait_for_unit("postgresql")
|
|
|
|
with subtest("Postgresql with extensions timescaledb and timescaledb_toolkit is available just after unit start"):
|
|
machine.succeed(
|
|
"sudo -u postgres psql -f ${test-sql}"
|
|
)
|
|
|
|
machine.fail(check_count("SELECT * FROM sth;", 3))
|
|
machine.succeed(check_count("SELECT * FROM sth;", 5))
|
|
machine.fail(check_count("SELECT * FROM sth;", 4))
|
|
|
|
machine.shutdown()
|
|
'';
|
|
};
|
|
in
|
|
# Not run by default, because this requires allowUnfree.
|
|
# To run these tests:
|
|
# NIXPKGS_ALLOW_UNFREE=1 nix-build -A nixosTests.postgresql.timescaledb
|
|
lib.dontRecurseIntoAttrs (genTests {
|
|
inherit makeTestFor;
|
|
filter = _: p: !p.pkgs.timescaledb.meta.broken;
|
|
})
|