mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-07-14 14:10:33 +03:00
14182c1970
Format all Nix files using the officially approved formatter, making the CI check introduced in the previous commit succeed: nix-build ci -A fmt.check This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153) of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166). This commit will lead to merge conflicts for a number of PRs, up to an estimated ~1100 (~33%) among the PRs with activity in the past 2 months, but that should be lower than what it would be without the previous [partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537). Merge conflicts caused by this commit can now automatically be resolved while rebasing using the [auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase). If you run into any problems regarding any of this, please reach out to the [formatting team](https://nixos.org/community/teams/formatting/) by pinging @NixOS/nix-formatting. (branch-equivalent to commit374e6bcc40)
51 lines
1.4 KiB
Nix
51 lines
1.4 KiB
Nix
{
|
|
system ? builtins.currentSystem,
|
|
config ? { },
|
|
pkgs ? import ../.. { inherit system config; },
|
|
lib ? pkgs.lib,
|
|
}:
|
|
|
|
let
|
|
|
|
inherit (import ../lib/testing-python.nix { inherit system pkgs; }) makeTest;
|
|
|
|
mkOCITest =
|
|
backend:
|
|
makeTest {
|
|
name = "oci-containers-${backend}";
|
|
|
|
meta.maintainers = lib.teams.serokell.members ++ (with lib.maintainers; [ benley ]);
|
|
|
|
nodes = {
|
|
${backend} =
|
|
{ pkgs, ... }:
|
|
{
|
|
virtualisation.oci-containers = {
|
|
inherit backend;
|
|
containers.nginx = {
|
|
image = "nginx-container";
|
|
imageStream = pkgs.dockerTools.examples.nginxStream;
|
|
ports = [ "8181:80" ];
|
|
};
|
|
};
|
|
|
|
# Stop systemd from killing remaining processes if ExecStop script
|
|
# doesn't work, so that proper stopping can be tested.
|
|
systemd.services."${backend}-nginx".serviceConfig.KillSignal = "SIGCONT";
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
${backend}.wait_for_unit("${backend}-nginx.service")
|
|
${backend}.wait_for_open_port(8181)
|
|
${backend}.wait_until_succeeds("curl -f http://localhost:8181 | grep Hello")
|
|
${backend}.succeed("systemctl stop ${backend}-nginx.service", timeout=10)
|
|
'';
|
|
};
|
|
|
|
in
|
|
lib.foldl' (attrs: backend: attrs // { ${backend} = mkOCITest backend; }) { } [
|
|
"docker"
|
|
"podman"
|
|
]
|