mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-11 12:15:34 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
73 lines
1.8 KiB
Nix
73 lines
1.8 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.irkerd;
|
|
ports = [ 6659 ];
|
|
in
|
|
{
|
|
options.services.irkerd = {
|
|
enable = lib.mkOption {
|
|
description = "Whether to enable irker, an IRC notification daemon.";
|
|
default = false;
|
|
type = lib.types.bool;
|
|
};
|
|
|
|
openPorts = lib.mkOption {
|
|
description = "Open ports in the firewall for irkerd";
|
|
default = false;
|
|
type = lib.types.bool;
|
|
};
|
|
|
|
listenAddress = lib.mkOption {
|
|
default = "localhost";
|
|
example = "0.0.0.0";
|
|
type = lib.types.str;
|
|
description = ''
|
|
Specifies the bind address on which the irker daemon listens.
|
|
The default is localhost.
|
|
|
|
Irker authors strongly warn about the risks of running this on
|
|
a publicly accessible interface, so change this with caution.
|
|
'';
|
|
};
|
|
|
|
nick = lib.mkOption {
|
|
default = "irker";
|
|
type = lib.types.str;
|
|
description = "Nick to use for irker";
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
systemd.services.irkerd = {
|
|
description = "Internet Relay Chat (IRC) notification daemon";
|
|
documentation = [
|
|
"man:irkerd(8)"
|
|
"man:irkerhook(1)"
|
|
"man:irk(1)"
|
|
];
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
ExecStart = "${pkgs.irker}/bin/irkerd -H ${cfg.listenAddress} -n ${cfg.nick}";
|
|
User = "irkerd";
|
|
};
|
|
};
|
|
|
|
environment.systemPackages = [ pkgs.irker ];
|
|
|
|
users.users.irkerd = {
|
|
description = "Irker daemon user";
|
|
isSystemUser = true;
|
|
group = "irkerd";
|
|
};
|
|
users.groups.irkerd = { };
|
|
|
|
networking.firewall.allowedTCPPorts = lib.mkIf cfg.openPorts ports;
|
|
networking.firewall.allowedUDPPorts = lib.mkIf cfg.openPorts ports;
|
|
};
|
|
}
|