mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-07-19 16:40:32 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
86 lines
2.2 KiB
Nix
86 lines
2.2 KiB
Nix
{
|
|
lib,
|
|
config,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
inherit (lib)
|
|
mkEnableOption
|
|
mkOption
|
|
mkIf
|
|
types
|
|
;
|
|
format = pkgs.formats.toml { };
|
|
cfg = config.services.hebbot;
|
|
settingsFile = format.generate "config.toml" cfg.settings;
|
|
mkTemplateOption =
|
|
templateName:
|
|
mkOption {
|
|
type = types.path;
|
|
description = ''
|
|
A path to the Markdown file for the ${templateName}.
|
|
'';
|
|
};
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.maintainers.raitobezarius ];
|
|
options.services.hebbot = {
|
|
enable = mkEnableOption "hebbot";
|
|
package = lib.mkPackageOption pkgs "hebbot" { };
|
|
botPasswordFile = mkOption {
|
|
type = types.path;
|
|
description = ''
|
|
A path to the password file for your bot.
|
|
|
|
Consider using a path that does not end up in your Nix store
|
|
as it would be world readable.
|
|
'';
|
|
};
|
|
templates = {
|
|
project = mkTemplateOption "project template";
|
|
report = mkTemplateOption "report template";
|
|
section = mkTemplateOption "section template";
|
|
};
|
|
settings = mkOption {
|
|
type = format.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration for Hebbot, see, for examples:
|
|
|
|
- <https://github.com/matrix-org/twim-config/blob/master/config.toml>
|
|
- <https://gitlab.gnome.org/Teams/Websites/thisweek.gnome.org/-/blob/main/hebbot/config.toml>
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.hebbot = {
|
|
description = "hebbot - a TWIM-style Matrix bot written in Rust";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
preStart = ''
|
|
ln -sf ${cfg.templates.project} ./project_template.md
|
|
ln -sf ${cfg.templates.report} ./report_template.md
|
|
ln -sf ${cfg.templates.section} ./section_template.md
|
|
ln -sf ${settingsFile} ./config.toml
|
|
'';
|
|
|
|
script = ''
|
|
export BOT_PASSWORD="$(cat $CREDENTIALS_DIRECTORY/bot-password-file)"
|
|
${lib.getExe cfg.package}
|
|
'';
|
|
|
|
serviceConfig = {
|
|
DynamicUser = true;
|
|
Restart = "on-failure";
|
|
LoadCredential = "bot-password-file:${cfg.botPasswordFile}";
|
|
RestartSec = "10s";
|
|
StateDirectory = "hebbot";
|
|
WorkingDirectory = "/var/lib/hebbot";
|
|
};
|
|
};
|
|
};
|
|
}
|