mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-12 20:55:31 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{
|
|
config,
|
|
pkgs,
|
|
lib,
|
|
...
|
|
}:
|
|
|
|
{
|
|
config = lib.mkIf (config.boot.initrd.enable && config.boot.initrd.systemd.enable) {
|
|
# Copy secrets into the initrd if they cannot be appended
|
|
boot.initrd.systemd.contents = lib.mkIf (!config.boot.loader.supportsInitrdSecrets) (
|
|
lib.mapAttrs' (
|
|
dest: source:
|
|
lib.nameValuePair "/.initrd-secrets/${dest}" { source = if source == null then dest else source; }
|
|
) config.boot.initrd.secrets
|
|
);
|
|
|
|
# Copy secrets to their respective locations
|
|
boot.initrd.systemd.services.initrd-nixos-copy-secrets =
|
|
lib.mkIf (config.boot.initrd.secrets != { })
|
|
{
|
|
description = "Copy secrets into place";
|
|
# Run as early as possible
|
|
wantedBy = [ "sysinit.target" ];
|
|
before = [
|
|
"cryptsetup-pre.target"
|
|
"shutdown.target"
|
|
];
|
|
conflicts = [ "shutdown.target" ];
|
|
unitConfig.DefaultDependencies = false;
|
|
|
|
# We write the secrets to /.initrd-secrets and move them because this allows
|
|
# secrets to be written to /run. If we put the secret directly to /run and
|
|
# drop this service, we'd mount the /run tmpfs over the secret, making it
|
|
# invisible in stage 2.
|
|
script = ''
|
|
for secret in $(cd /.initrd-secrets; find . -type f -o -type l); do
|
|
mkdir -p "$(dirname "/$secret")"
|
|
cp "/.initrd-secrets/$secret" "/$secret"
|
|
done
|
|
'';
|
|
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
RemainAfterExit = true;
|
|
};
|
|
};
|
|
# The script needs this
|
|
boot.initrd.systemd.extraBin.find = "${pkgs.findutils}/bin/find";
|
|
};
|
|
}
|