mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-07-19 16:40:32 +03:00
d9d87c5196
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build https://github.com/infinisil/treewide-nixpkgs-reformat-script/archive/a08b3a4d199c6124ac5b36a889d9099b4383463f.tar.gz \
--argstr baseRev 0128fbb0a5
result/bin/apply-formatting $NIXPKGS_PATH
91 lines
2.2 KiB
Nix
91 lines
2.2 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
|
|
defaultUserGroup = "usbmux";
|
|
apple = "05ac";
|
|
|
|
cfg = config.services.usbmuxd;
|
|
|
|
in
|
|
|
|
{
|
|
options.services.usbmuxd = {
|
|
|
|
enable = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Enable the usbmuxd ("USB multiplexing daemon") service. This daemon is
|
|
in charge of multiplexing connections over USB to an iOS device. This is
|
|
needed for transferring data from and to iOS devices (see ifuse). Also
|
|
this may enable plug-n-play tethering for iPhones.
|
|
'';
|
|
};
|
|
|
|
user = lib.mkOption {
|
|
type = lib.types.str;
|
|
default = defaultUserGroup;
|
|
description = ''
|
|
The user usbmuxd should use to run after startup.
|
|
'';
|
|
};
|
|
|
|
group = lib.mkOption {
|
|
type = lib.types.str;
|
|
default = defaultUserGroup;
|
|
description = ''
|
|
The group usbmuxd should use to run after startup.
|
|
'';
|
|
};
|
|
|
|
package = lib.mkOption {
|
|
type = lib.types.package;
|
|
default = pkgs.usbmuxd;
|
|
defaultText = lib.literalExpression "pkgs.usbmuxd";
|
|
description = "Which package to use for the usbmuxd daemon.";
|
|
relatedPackages = [
|
|
"usbmuxd"
|
|
"usbmuxd2"
|
|
];
|
|
};
|
|
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
|
|
users.users = lib.optionalAttrs (cfg.user == defaultUserGroup) {
|
|
${cfg.user} = {
|
|
description = "usbmuxd user";
|
|
group = cfg.group;
|
|
isSystemUser = true;
|
|
};
|
|
};
|
|
|
|
users.groups = lib.optionalAttrs (cfg.group == defaultUserGroup) {
|
|
${cfg.group} = { };
|
|
};
|
|
|
|
# Give usbmuxd permission for Apple devices
|
|
services.udev.extraRules = ''
|
|
SUBSYSTEM=="usb", ATTR{idVendor}=="${apple}", GROUP="${cfg.group}"
|
|
'';
|
|
|
|
systemd.services.usbmuxd = {
|
|
description = "usbmuxd";
|
|
wantedBy = [ "multi-user.target" ];
|
|
unitConfig.Documentation = "man:usbmuxd(8)";
|
|
serviceConfig = {
|
|
# Trigger the udev rule manually. This doesn't require replugging the
|
|
# device when first enabling the option to get it to work
|
|
ExecStartPre = "${config.systemd.package}/bin/udevadm trigger -s usb -a idVendor=${apple}";
|
|
ExecStart = "${cfg.package}/bin/usbmuxd -U ${cfg.user} -v";
|
|
};
|
|
};
|
|
|
|
};
|
|
}
|