mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-07-19 08:31:01 +03:00
d9d87c5196
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build https://github.com/infinisil/treewide-nixpkgs-reformat-script/archive/a08b3a4d199c6124ac5b36a889d9099b4383463f.tar.gz \
--argstr baseRev 0128fbb0a5
result/bin/apply-formatting $NIXPKGS_PATH
87 lines
2.3 KiB
Nix
87 lines
2.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
options,
|
|
...
|
|
}:
|
|
|
|
let
|
|
cfg = config.services.prometheus.exporters.wireguard;
|
|
inherit (lib)
|
|
mkOption
|
|
types
|
|
mkRenamedOptionModule
|
|
mkEnableOption
|
|
optionalString
|
|
escapeShellArg
|
|
;
|
|
in
|
|
{
|
|
port = 9586;
|
|
imports = [
|
|
(mkRenamedOptionModule [ "addr" ] [ "listenAddress" ])
|
|
({
|
|
options.warnings = options.warnings;
|
|
options.assertions = options.assertions;
|
|
})
|
|
];
|
|
extraOpts = {
|
|
verbose = mkEnableOption "verbose logging mode for prometheus-wireguard-exporter";
|
|
|
|
wireguardConfig = mkOption {
|
|
type = with types; nullOr (either path str);
|
|
default = null;
|
|
|
|
description = ''
|
|
Path to the Wireguard Config to
|
|
[add the peer's name to the stats of a peer](https://github.com/MindFlavor/prometheus_wireguard_exporter/tree/2.0.0#usage).
|
|
|
|
Please note that `networking.wg-quick` is required for this feature
|
|
as `networking.wireguard` uses
|
|
{manpage}`wg(8)`
|
|
to set the peers up.
|
|
'';
|
|
};
|
|
|
|
singleSubnetPerField = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
By default, all allowed IPs and subnets are comma-separated in the
|
|
`allowed_ips` field. With this option enabled,
|
|
a single IP and subnet will be listed in fields like `allowed_ip_0`,
|
|
`allowed_ip_1` and so on.
|
|
'';
|
|
};
|
|
|
|
withRemoteIp = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether or not the remote IP of a WireGuard peer should be exposed via prometheus.
|
|
'';
|
|
};
|
|
};
|
|
serviceOpts = {
|
|
path = [ pkgs.wireguard-tools ];
|
|
|
|
serviceConfig = {
|
|
AmbientCapabilities = [ "CAP_NET_ADMIN" ];
|
|
CapabilityBoundingSet = [ "CAP_NET_ADMIN" ];
|
|
ExecStart = ''
|
|
${pkgs.prometheus-wireguard-exporter}/bin/prometheus_wireguard_exporter \
|
|
-p ${toString cfg.port} \
|
|
-l ${cfg.listenAddress} \
|
|
${optionalString cfg.verbose "-v true"} \
|
|
${optionalString cfg.singleSubnetPerField "-s true"} \
|
|
${optionalString cfg.withRemoteIp "-r true"} \
|
|
${optionalString (cfg.wireguardConfig != null) "-n ${escapeShellArg cfg.wireguardConfig}"}
|
|
'';
|
|
RestrictAddressFamilies = [
|
|
# Need AF_NETLINK to collect data
|
|
"AF_NETLINK"
|
|
];
|
|
};
|
|
};
|
|
}
|