mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-22 01:11:02 +03:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
# This module adds a scripted iPXE entry to the GRUB boot menu.
|
|
|
|
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
scripts = builtins.attrNames config.boot.loader.grub.ipxe;
|
|
|
|
grubEntry = name:
|
|
''
|
|
menuentry "iPXE - ${name}" {
|
|
linux16 @bootRoot@/ipxe.lkrn
|
|
initrd16 @bootRoot@/${name}.ipxe
|
|
}
|
|
|
|
'';
|
|
|
|
scriptFile = name:
|
|
let
|
|
value = builtins.getAttr name config.boot.loader.grub.ipxe;
|
|
in
|
|
if builtins.typeOf value == "path" then value
|
|
else builtins.toFile "${name}.ipxe" value;
|
|
in
|
|
{
|
|
options =
|
|
{ boot.loader.grub.ipxe = mkOption {
|
|
type = types.attrsOf (types.either types.path types.str);
|
|
description = ''
|
|
Set of iPXE scripts available for
|
|
booting from the GRUB boot menu.
|
|
'';
|
|
default = { };
|
|
example = literalExpression ''
|
|
{ demo = '''
|
|
#!ipxe
|
|
dhcp
|
|
chain http://boot.ipxe.org/demo/boot.php
|
|
''';
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf (builtins.length scripts != 0) {
|
|
|
|
boot.loader.grub.extraEntries = toString (map grubEntry scripts);
|
|
|
|
boot.loader.grub.extraFiles =
|
|
{ "ipxe.lkrn" = "${pkgs.ipxe}/ipxe.lkrn"; }
|
|
//
|
|
builtins.listToAttrs ( map
|
|
(name: { name = name+".ipxe"; value = scriptFile name; })
|
|
scripts
|
|
);
|
|
};
|
|
|
|
}
|