mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-07-14 22:20:30 +03:00
d9d87c5196
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build https://github.com/infinisil/treewide-nixpkgs-reformat-script/archive/a08b3a4d199c6124ac5b36a889d9099b4383463f.tar.gz \
--argstr baseRev 0128fbb0a5
result/bin/apply-formatting $NIXPKGS_PATH
117 lines
3.2 KiB
Nix
117 lines
3.2 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.networkd-dispatcher;
|
|
|
|
in
|
|
{
|
|
|
|
options = {
|
|
services.networkd-dispatcher = {
|
|
|
|
enable = mkEnableOption ''
|
|
Networkd-dispatcher service for systemd-networkd connection status
|
|
change. See [upstream instructions](https://gitlab.com/craftyguy/networkd-dispatcher)
|
|
for usage
|
|
'';
|
|
|
|
rules = mkOption {
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{ "restart-tor" = {
|
|
onState = ["routable" "off"];
|
|
script = '''
|
|
#!''${pkgs.runtimeShell}
|
|
if [[ $IFACE == "wlan0" && $AdministrativeState == "configured" ]]; then
|
|
echo "Restarting Tor ..."
|
|
systemctl restart tor
|
|
fi
|
|
exit 0
|
|
''';
|
|
};
|
|
};
|
|
'';
|
|
description = ''
|
|
Declarative configuration of networkd-dispatcher rules. See
|
|
[upstream instructions](https://gitlab.com/craftyguy/networkd-dispatcher)
|
|
for an introduction and example scripts.
|
|
'';
|
|
type = types.attrsOf (
|
|
types.submodule {
|
|
options = {
|
|
onState = mkOption {
|
|
type = types.listOf (
|
|
types.enum [
|
|
"routable"
|
|
"dormant"
|
|
"no-carrier"
|
|
"off"
|
|
"carrier"
|
|
"degraded"
|
|
"configuring"
|
|
"configured"
|
|
]
|
|
);
|
|
default = null;
|
|
description = ''
|
|
List of names of the systemd-networkd operational states which
|
|
should trigger the script. See <https://www.freedesktop.org/software/systemd/man/networkctl.html>
|
|
for a description of the specific state type.
|
|
'';
|
|
};
|
|
script = mkOption {
|
|
type = types.lines;
|
|
description = ''
|
|
Shell commands executed on specified operational states.
|
|
'';
|
|
};
|
|
};
|
|
}
|
|
);
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
systemd = {
|
|
packages = [ pkgs.networkd-dispatcher ];
|
|
services.networkd-dispatcher = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
# Override existing ExecStart definition
|
|
serviceConfig.ExecStart =
|
|
let
|
|
scriptDir = pkgs.symlinkJoin {
|
|
name = "networkd-dispatcher-script-dir";
|
|
paths = lib.mapAttrsToList (
|
|
name: cfg:
|
|
(map (
|
|
state:
|
|
pkgs.writeTextFile {
|
|
inherit name;
|
|
text = cfg.script;
|
|
destination = "/${state}.d/${name}";
|
|
executable = true;
|
|
}
|
|
) cfg.onState)
|
|
) cfg.rules;
|
|
};
|
|
in
|
|
[
|
|
""
|
|
"${pkgs.networkd-dispatcher}/bin/networkd-dispatcher -v --script-dir ${scriptDir} $networkd_dispatcher_args"
|
|
];
|
|
};
|
|
};
|
|
|
|
};
|
|
}
|