mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-22 17:31:04 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
70 lines
2.3 KiB
Nix
70 lines
2.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.services.offlineimap;
|
|
in
|
|
{
|
|
|
|
options.services.offlineimap = {
|
|
enable = lib.mkEnableOption "OfflineIMAP, a software to dispose your mailbox(es) as a local Maildir(s)";
|
|
|
|
install = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to install a user service for Offlineimap. Once
|
|
the service is started, emails will be fetched automatically.
|
|
|
|
The service must be manually started for each user with
|
|
"systemctl --user start offlineimap" or globally through
|
|
{var}`services.offlineimap.enable`.
|
|
'';
|
|
};
|
|
|
|
package = lib.mkPackageOption pkgs "offlineimap" { };
|
|
|
|
path = lib.mkOption {
|
|
type = lib.types.listOf lib.types.path;
|
|
default = [ ];
|
|
example = lib.literalExpression "[ pkgs.pass pkgs.bash pkgs.notmuch ]";
|
|
description = "List of derivations to put in Offlineimap's path.";
|
|
};
|
|
|
|
onCalendar = lib.mkOption {
|
|
type = lib.types.str;
|
|
default = "*:0/3"; # every 3 minutes
|
|
description = "How often is offlineimap started. Default is '*:0/3' meaning every 3 minutes. See systemd.time(7) for more information about the format.";
|
|
};
|
|
|
|
timeoutStartSec = lib.mkOption {
|
|
type = lib.types.str;
|
|
default = "120sec"; # Kill if still alive after 2 minutes
|
|
description = "How long waiting for offlineimap before killing it. Default is '120sec' meaning every 2 minutes. See systemd.time(7) for more information about the format.";
|
|
};
|
|
};
|
|
config = lib.mkIf (cfg.enable || cfg.install) {
|
|
systemd.user.services.offlineimap = {
|
|
description = "Offlineimap: a software to dispose your mailbox(es) as a local Maildir(s)";
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
ExecStart = "${cfg.package}/bin/offlineimap -u syslog -o -1";
|
|
TimeoutStartSec = cfg.timeoutStartSec;
|
|
};
|
|
path = cfg.path;
|
|
};
|
|
environment.systemPackages = [ cfg.package ];
|
|
systemd.user.timers.offlineimap = {
|
|
description = "offlineimap timer";
|
|
timerConfig = {
|
|
Unit = "offlineimap.service";
|
|
OnCalendar = cfg.onCalendar;
|
|
# start immediately after computer is started:
|
|
Persistent = "true";
|
|
};
|
|
} // lib.optionalAttrs cfg.enable { wantedBy = [ "default.target" ]; };
|
|
};
|
|
}
|