mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-19 07:59:24 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
101 lines
2.4 KiB
Nix
101 lines
2.4 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.lighttpd.cgit;
|
|
pathPrefix = optionalString (stringLength cfg.subdir != 0) ("/" + cfg.subdir);
|
|
configFile = pkgs.writeText "cgitrc" ''
|
|
# default paths to static assets
|
|
css=${pathPrefix}/cgit.css
|
|
logo=${pathPrefix}/cgit.png
|
|
favicon=${pathPrefix}/favicon.ico
|
|
|
|
# user configuration
|
|
${cfg.configText}
|
|
'';
|
|
in
|
|
{
|
|
|
|
options.services.lighttpd.cgit = {
|
|
|
|
enable = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
If true, enable cgit (fast web interface for git repositories) as a
|
|
sub-service in lighttpd.
|
|
'';
|
|
};
|
|
|
|
subdir = mkOption {
|
|
default = "cgit";
|
|
example = "";
|
|
type = types.str;
|
|
description = ''
|
|
The subdirectory in which to serve cgit. The web application will be
|
|
accessible at http://yourserver/''${subdir}
|
|
'';
|
|
};
|
|
|
|
configText = mkOption {
|
|
default = "";
|
|
example = literalExpression ''
|
|
'''
|
|
source-filter=''${pkgs.cgit}/lib/cgit/filters/syntax-highlighting.py
|
|
about-filter=''${pkgs.cgit}/lib/cgit/filters/about-formatting.sh
|
|
cache-size=1000
|
|
scan-path=/srv/git
|
|
'''
|
|
'';
|
|
type = types.lines;
|
|
description = ''
|
|
Verbatim contents of the cgit runtime configuration file. Documentation
|
|
(with cgitrc example file) is available in "man cgitrc". Or online:
|
|
http://git.zx2c4.com/cgit/tree/cgitrc.5.txt
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
# make the cgitrc manpage available
|
|
environment.systemPackages = [ pkgs.cgit ];
|
|
|
|
# declare module dependencies
|
|
services.lighttpd.enableModules = [
|
|
"mod_cgi"
|
|
"mod_alias"
|
|
"mod_setenv"
|
|
];
|
|
|
|
services.lighttpd.extraConfig = ''
|
|
$HTTP["url"] =~ "^/${cfg.subdir}" {
|
|
cgi.assign = (
|
|
"cgit.cgi" => "${pkgs.cgit}/cgit/cgit.cgi"
|
|
)
|
|
alias.url = (
|
|
"${pathPrefix}/cgit.css" => "${pkgs.cgit}/cgit/cgit.css",
|
|
"${pathPrefix}/cgit.png" => "${pkgs.cgit}/cgit/cgit.png",
|
|
"${pathPrefix}" => "${pkgs.cgit}/cgit/cgit.cgi"
|
|
)
|
|
setenv.add-environment = (
|
|
"CGIT_CONFIG" => "${configFile}"
|
|
)
|
|
}
|
|
'';
|
|
|
|
systemd.services.lighttpd.preStart = ''
|
|
mkdir -p /var/cache/cgit
|
|
chown lighttpd:lighttpd /var/cache/cgit
|
|
'';
|
|
|
|
};
|
|
|
|
}
|