mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-09 19:13:26 +03:00
dd0f03a56c
They are not doing anything right now. This is in preparation for their complete removal from the tree. Note: several changes that affect the derivation inputs (e.g. removal of references to stub paths in build instructions) were left out. They will be cleaned up the next iteration and will require special care. Note: this PR is a result of a mix of ugly regex (not AST) based automation and some manual labor. For reference, the regex automation part was hacked in: https://github.com/booxter/nix-clean-apple_sdk Signed-off-by: Ihar Hrachyshka <ihar.hrachyshka@gmail.com>
80 lines
1.6 KiB
Nix
80 lines
1.6 KiB
Nix
{
|
|
lib,
|
|
rustPlatform,
|
|
fetchFromGitHub,
|
|
protobuf,
|
|
rustfmt,
|
|
pkg-config,
|
|
openssl,
|
|
}:
|
|
|
|
let
|
|
version = "0.2.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "talaia-labs";
|
|
repo = "rust-teos";
|
|
rev = "v${version}";
|
|
hash = "sha256-UrzH9xmhVq12TcSUQ1AihCG1sNGcy/N8LDsZINVKFkY=";
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/talaia-labs/rust-teos";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ seberm ];
|
|
};
|
|
updateScript = ./update.sh;
|
|
in
|
|
{
|
|
teos = rustPlatform.buildRustPackage {
|
|
pname = "teos";
|
|
inherit version src;
|
|
|
|
useFetchCargoVendor = true;
|
|
cargoHash = "sha256-lod5I94T4wGwXEDtvh2AyaDYM0byCfaSBP8emKV7+3M=";
|
|
|
|
buildAndTestSubdir = "teos";
|
|
|
|
nativeBuildInputs = [
|
|
protobuf
|
|
rustfmt
|
|
];
|
|
|
|
passthru.updateScript = updateScript;
|
|
|
|
__darwinAllowLocalNetworking = true;
|
|
|
|
meta = meta // {
|
|
description = "Lightning watchtower compliant with BOLT13, written in Rust";
|
|
};
|
|
};
|
|
|
|
teos-watchtower-plugin = rustPlatform.buildRustPackage {
|
|
pname = "teos-watchtower-plugin";
|
|
inherit version src;
|
|
|
|
useFetchCargoVendor = true;
|
|
cargoHash = "sha256-lod5I94T4wGwXEDtvh2AyaDYM0byCfaSBP8emKV7+3M=";
|
|
|
|
buildAndTestSubdir = "watchtower-plugin";
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
protobuf
|
|
rustfmt
|
|
];
|
|
|
|
buildInputs = [
|
|
openssl
|
|
];
|
|
|
|
passthru.updateScript = updateScript;
|
|
|
|
__darwinAllowLocalNetworking = true;
|
|
|
|
meta = meta // {
|
|
description = "Lightning watchtower plugin for clightning";
|
|
mainProgram = "watchtower-client";
|
|
};
|
|
};
|
|
}
|