mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-09 19:13:26 +03:00
dd0f03a56c
They are not doing anything right now. This is in preparation for their complete removal from the tree. Note: several changes that affect the derivation inputs (e.g. removal of references to stub paths in build instructions) were left out. They will be cleaned up the next iteration and will require special care. Note: this PR is a result of a mix of ugly regex (not AST) based automation and some manual labor. For reference, the regex automation part was hacked in: https://github.com/booxter/nix-clean-apple_sdk Signed-off-by: Ihar Hrachyshka <ihar.hrachyshka@gmail.com>
80 lines
1.8 KiB
Nix
80 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
rustPlatform,
|
|
fetchFromGitHub,
|
|
installShellFiles,
|
|
stdenv,
|
|
pkg-config,
|
|
fontconfig,
|
|
xorg,
|
|
libxkbcommon,
|
|
wayland,
|
|
libGL,
|
|
openssl,
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "inlyne";
|
|
version = "0.5.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Inlyne-Project";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-ueE1NKbCMBUBrrdsHkwZ5Yv6LD3tQL3ZAk2O4xoYOcw=";
|
|
};
|
|
|
|
useFetchCargoVendor = true;
|
|
cargoHash = "sha256-jSUqpryUgOL0qo0gbbH4s24krrPsLOSNc6FQUEUeeUQ=";
|
|
|
|
nativeBuildInputs =
|
|
[
|
|
installShellFiles
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
|
|
fontconfig
|
|
xorg.libXcursor
|
|
xorg.libXi
|
|
xorg.libXrandr
|
|
xorg.libxcb
|
|
wayland
|
|
libxkbcommon
|
|
openssl
|
|
];
|
|
|
|
checkFlags = lib.optionals stdenv.hostPlatform.isDarwin [
|
|
# time out on darwin
|
|
"--skip=interpreter::tests::centered_image_with_size_align_and_link"
|
|
"--skip=watcher::tests::the_gauntlet"
|
|
];
|
|
|
|
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd inlyne \
|
|
--bash completions/inlyne.bash \
|
|
--fish completions/inlyne.fish \
|
|
--zsh completions/_inlyne
|
|
'';
|
|
|
|
postFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
patchelf $out/bin/inlyne \
|
|
--add-rpath ${
|
|
lib.makeLibraryPath [
|
|
libGL
|
|
xorg.libX11
|
|
]
|
|
}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "GPU powered browserless markdown viewer";
|
|
homepage = "https://github.com/Inlyne-Project/inlyne";
|
|
changelog = "https://github.com/Inlyne-Project/inlyne/releases/tag/${src.rev}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ figsoda ];
|
|
mainProgram = "inlyne";
|
|
};
|
|
}
|