mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-10 19:55:41 +03:00
374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
76 lines
1.8 KiB
Nix
76 lines
1.8 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
WorkingDirectory = "/var/lib/tox-bootstrapd";
|
|
PIDFile = "${WorkingDirectory}/pid";
|
|
|
|
pkg = pkgs.libtoxcore;
|
|
cfg = config.services.toxBootstrapd;
|
|
cfgFile = builtins.toFile "tox-bootstrapd.conf" ''
|
|
port = ${toString cfg.port}
|
|
keys_file_path = "${WorkingDirectory}/keys"
|
|
pid_file_path = "${PIDFile}"
|
|
${cfg.extraConfig}
|
|
'';
|
|
in
|
|
{
|
|
options = {
|
|
services.toxBootstrapd = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to enable the Tox DHT bootstrap daemon.
|
|
'';
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 33445;
|
|
description = "Listening port (UDP).";
|
|
};
|
|
|
|
keysFile = mkOption {
|
|
type = types.str;
|
|
default = "${WorkingDirectory}/keys";
|
|
description = "Node key file.";
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Configuration for bootstrap daemon.
|
|
See <https://github.com/irungentoo/toxcore/blob/master/other/bootstrap_daemon/tox-bootstrapd.conf>
|
|
and <https://wiki.tox.chat/users/nodes>.
|
|
'';
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf config.services.toxBootstrapd.enable {
|
|
|
|
systemd.services.tox-bootstrapd = {
|
|
description = "Tox DHT bootstrap daemon";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
ExecStart = "${pkg}/bin/tox-bootstrapd --config=${cfgFile}";
|
|
Type = "forking";
|
|
inherit PIDFile WorkingDirectory;
|
|
AmbientCapabilities = [ "CAP_NET_BIND_SERVICE" ];
|
|
DynamicUser = true;
|
|
StateDirectory = "tox-bootstrapd";
|
|
};
|
|
};
|
|
|
|
};
|
|
}
|