mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-06-10 11:45:45 +03:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
118 lines
3.3 KiB
Nix
118 lines
3.3 KiB
Nix
{
|
|
config,
|
|
pkgs,
|
|
lib,
|
|
...
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.chatgpt-retrieval-plugin;
|
|
in
|
|
{
|
|
options.services.chatgpt-retrieval-plugin = {
|
|
enable = mkEnableOption "chatgpt-retrieval-plugin service";
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 8080;
|
|
description = "Port the chatgpt-retrieval-plugin service listens on.";
|
|
};
|
|
|
|
host = mkOption {
|
|
type = types.str;
|
|
default = "127.0.0.1";
|
|
example = "0.0.0.0";
|
|
description = "The hostname or IP address for chatgpt-retrieval-plugin to bind to.";
|
|
};
|
|
|
|
bearerTokenPath = mkOption {
|
|
type = types.path;
|
|
description = ''
|
|
Path to the secret bearer token used for the http api authentication.
|
|
'';
|
|
default = "";
|
|
example = "config.age.secrets.CHATGPT_RETRIEVAL_PLUGIN_BEARER_TOKEN.path";
|
|
};
|
|
|
|
openaiApiKeyPath = mkOption {
|
|
type = types.path;
|
|
description = ''
|
|
Path to the secret openai api key used for embeddings.
|
|
'';
|
|
default = "";
|
|
example = "config.age.secrets.CHATGPT_RETRIEVAL_PLUGIN_OPENAI_API_KEY.path";
|
|
};
|
|
|
|
datastore = mkOption {
|
|
type = types.enum [
|
|
"pinecone"
|
|
"weaviate"
|
|
"zilliz"
|
|
"milvus"
|
|
"qdrant"
|
|
"redis"
|
|
];
|
|
default = "qdrant";
|
|
description = "This specifies the vector database provider you want to use to store and query embeddings.";
|
|
};
|
|
|
|
qdrantCollection = mkOption {
|
|
type = types.str;
|
|
description = ''
|
|
name of the qdrant collection used to store documents.
|
|
'';
|
|
default = "document_chunks";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
assertions = [
|
|
{
|
|
assertion = cfg.bearerTokenPath != "";
|
|
message = "services.chatgpt-retrieval-plugin.bearerTokenPath should not be an empty string.";
|
|
}
|
|
{
|
|
assertion = cfg.openaiApiKeyPath != "";
|
|
message = "services.chatgpt-retrieval-plugin.openaiApiKeyPath should not be an empty string.";
|
|
}
|
|
];
|
|
|
|
systemd.services.chatgpt-retrieval-plugin = {
|
|
description = "ChatGPT Retrieval Plugin";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
LoadCredential = [
|
|
"BEARER_TOKEN:${cfg.bearerTokenPath}"
|
|
"OPENAI_API_KEY:${cfg.openaiApiKeyPath}"
|
|
];
|
|
StateDirectory = "chatgpt-retrieval-plugin";
|
|
StateDirectoryMode = "0755";
|
|
};
|
|
|
|
# it doesn't make sense to pass secrets as env vars, this is a hack until
|
|
# upstream has proper secret management.
|
|
script = ''
|
|
export BEARER_TOKEN=$(${pkgs.systemd}/bin/systemd-creds cat BEARER_TOKEN)
|
|
export OPENAI_API_KEY=$(${pkgs.systemd}/bin/systemd-creds cat OPENAI_API_KEY)
|
|
exec ${pkgs.chatgpt-retrieval-plugin}/bin/start --host ${cfg.host} --port ${toString cfg.port}
|
|
'';
|
|
|
|
environment = {
|
|
DATASTORE = cfg.datastore;
|
|
QDRANT_COLLECTION = mkIf (cfg.datastore == "qdrant") cfg.qdrantCollection;
|
|
};
|
|
};
|
|
|
|
systemd.tmpfiles.rules = [
|
|
# create the directory for static files for fastapi
|
|
"C /var/lib/chatgpt-retrieval-plugin/.well-known - - - - ${pkgs.chatgpt-retrieval-plugin}/${pkgs.python3Packages.python.sitePackages}/.well-known"
|
|
];
|
|
};
|
|
}
|